Где скачать kdenlive 0.9.4 x64 для Arch?

Модератор: Модераторы разделов

Ответить
awua
Сообщения: 594

Где скачать kdenlive 0.9.4 x64 для Arch?

Сообщение awua »

Arch Rollback Machine содержит только последнюю версию сий программы. Хотелось бы откатиться на шаг назад, но не могу найти пакет. Кто-нибудь знает, где его ещё можно скачать?
Спасибо сказали:
Аватара пользователя
ATWA
Сообщения: 7
ОС: Arch Linux

Re: Где скачать kdenlive 0.9.4 x64 для Arch?

Сообщение ATWA »

PKGBUILD

Код: Выделить всё

# $Id$
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Zuf <kontakt.zuf@gmail.com>
# Contributor: Darwin Bautista <djclue917@gmail.com>

pkgname=kdenlive
pkgver=0.9.4
pkgrel=2
pkgdesc="A non-linear video editor for Linux"
arch=('i686' 'x86_64')
# http://download.kde.org/stable/kdenlive/
url="http://www.kdenlive.org/"
license=('GPL')
depends=('kdebase-runtime' 'mlt' 'qjson' 'libqzeitgeist')
makedepends=('automoc4' 'cmake' 'gettext' 'mesa' 'glu')
optdepends=('recordmydesktop: screen capture'
            'dvdauthor: dvd creation'
            'dvgrab: firewire capture'
            'xine-ui: dvd preview'
            'cdrkit: dvd iso image creation')
install=kdenlive.install
options=('docs')
source=(http://download.kde.org/stable/kdenlive/$pkgver/src/kdenlive-$pkgver.tar.bz2)
md5sums=('fed17b584aca6a9811a49f2348b4f6db')

build() {
  export LDFLAGS="$LDFLAGS -lX11"
  cd "${srcdir}"
  mkdir -p build
  cd build
  cmake ../kdenlive-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=/usr/lib \
    -DLINK_LIBRARIES=-lX11
  make
}

package() {
  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install
}

kdenlive.install

Код: Выделить всё

post_install() {
  update-mime-database usr/share/mime &> /dev/null
  xdg-icon-resource forceupdate --theme hicolor &> /dev/null
}

post_upgrade() {
  post_install
}

post_remove() {
  post_install
}

Отсюда.
Спасибо сказали:
Ответить